HLAB 2020-2021

第1回　基礎的な図形と座標変換

本年度もGDL教科書(Kindle版はこちら)を用いてモデリングの講習を進めていきます。本ページでは、講習会でのモデリング課題とその解答例を載せていきます。

第1回目の講習では、基本的な図形の生成と座標変換を扱いました。座標変換と共に「Wall Clock」ではFOR文を、「Wood Puzzle」ではPRISM_のコマンドを用いるという、初回としてはやや難しい内容を扱いました。

Wall Clock

座標変換とFOR文を用いて、掛け時計のモデリング課題です。文字盤の印と時計の針を配置する際に行う回転によるx,y,z軸の扱い方は、三次元空間上でのモデリングで非常に重要になっていく考え方です。また、印は数値モデリングの特徴を活かし、FOR文によって生成していきます。

!! 時計

!! -------------- 土台部分 ------------
MATERIAL 52	!! 土台の材質

hBack = 0.075	!! 機械部の高さ
rBack = 0.2	!! 機械部の半径

CYLIND hBack, rBack

ADDZ hBack

hFront = 0.025	!! 文字盤の高さ
rFront = 0.22	!! 文字盤の半径

CYLIND hFront, rFront

!! -------------- 印・針 ------------
MATERIAL 49	!! 印・針の材質

ADDZ hFront

hCenter = 0.01	!! 針軸の高さ
rCenter = 0.01	!! 針軸の半径

CYLIND hCenter, rCenter

!! 印部分
xNum = 0.01	!! 印の幅
yNum = 0.03	!! 印の長さ
zNum = hCenter 	!! 印の高さ
rNum = rFront - ( yNum + 0.02 )	!! 印と文字盤中心との距離

FOR i = 1 to 12
	ROTZ 30 * i	!! 30°の倍数で回転
	ADDY rNum	!! 中心から移動させる
	ADDX -xNum / 2	!! 印の軸を合わせる
	BRICK xNum, yNum, zNum
	DEL 3
NEXT i

!! 針部分
xHour = xNum * 2	!! 短針の幅
yHour = 0.075	!! 短針の長さ
zHour = hCenter / 5	!! 短針の高さ

ADDX -xHour / 2
ADDZ hCenter / 5
BRICK xHour, yHour, zHour

DEL 2

xMinute = xNum 	!! 長針の幅
yMinute = 0.15	!! 長針の長さ
zMinute = hCenter / 5	!! 長針の高さ

ROTZ -90
ADDX -xMinute / 2
ADDZ hCenter * 3 / 5
BRICK xMinute, yMinute, zMinute

DEL TOP

Wood Puzzle

こちらの課題では、PRISMやPRISM_を用いて切り欠きのある部材を生成します。PRISM_ではステータスコードを使用します。今回の課題で用いたもの以外にも様々な種類があるので、他のステータスコードも試してみましょう。

!! 三本組木
d = 11	!! 部材厚み
w = 2 * d	!! 部材高さ
a = d / 2	!! 部材に空く穴のオフセット(高さ)
x = 2	!! 部材に空く穴のオフセット(幅)

!! 一本目
ROTY 90
ADDZ -w / 4	!! 軸を部材中心に移動

PRISM_ 10, d,
	-( x + w / 2 ), -w / 2, 15,
	-( x + w / 2 ), w / 2, 15,
	x + w / 2, w / 2, 15,
	x + w / 2, -w / 2, 15,
	-( x + w / 2 ), -w / 2, -1,
	-w / 2, -d / 2, 15,
	-w / 2, d / 2, 15,
	w / 2, d / 2, 15,
	w / 2, -d / 2, 15,
	-w / 2, -d / 2, -1
DEL 2

!! 二本目
ROTZ 90
ADDZ  -w / 4	!! 軸を部材中心に移動

PRISM 12, d,
	-( x + w / 2 ), -w / 2,
	-( x + w / 2 ), w / 2,
	-d / 2, w / 2,
	-d / 2, d / 2,
	-w / 2, d / 2,
	-w / 2, -d / 2,
	w / 2, -d / 2,
	w / 2, d / 2,
	d / 2, d / 2,
	d / 2, w / 2,
	x + w / 2, w / 2,
	x + w / 2, -w / 2
DEL 2

!! 三本目
ROTX 90
ADDZ -w / 4	!! 軸を部材中心に移動

PRISM 10, d,
	-( x + w / 2 ), -w / 2,
	-( x + w / 2 ), w / 2,
	-a, w / 2,
	-a, -d / 2,
	2 * a, -d / 2,
	2 * a, d / 2,
	0, d / 2,
	0, w / 2,
	x + w / 2, w / 2,
	x + w / 2, -w / 2
DEL TOP

今回の課題では回転と座標変換を同時に行う場面が多かったと思います。図のように、ワイヤ―フレームに切り替えて作業していくと、入り組んだカタチを作りやすくなります。始めは慣れないと思いますが、このような座標変換の扱い方を身に付け、自分の作りたいものを正確にモデリングできるように訓練しましょう。